Initial commit

2025-01-25 12:30:00 +01:00
commit 2013d04cf7
34 changed files with 5958 additions and 0 deletions
@@ -0,0 +1,61 @@
+{
+  description = "Backend for GéJDR, a Discord helper tool for the TTRPG L'Anneau Unique";
+
+  inputs = {
+    nixpkgs.url      = "github:nixos/nixpkgs/nixos-unstable";
+    flake-utils.url  = "github:numtide/flake-utils";
+    rust-overlay.url = "github:oxalica/rust-overlay";
+  };
+
+  outputs = { self, nixpkgs, flake-utils, rust-overlay }:
+    flake-utils.lib.eachSystem ["x86_64-linux"] (system:
+      let
+        overlays = [ (import rust-overlay) ];
+        pkgs = import nixpkgs { inherit system overlays; };
+        rustVersion = (pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml);
+        rustPlatform = pkgs.makeRustPlatform {
+          cargo = rustVersion;
+          rustc = rustVersion;
+        };
+
+        appName = "gege-jdr-backend";
+
+        appRustBuild = rustPlatform.buildRustPackage {
+          pname = appName;
+          version = "0.1.0";
+          src = ./.;
+          cargoLock.lockFile = ./Cargo.lock;
+        };
+
+        dockerImage = pkgs.dockerTools.buildLayeredImage {
+          name = appName;
+          config = {
+            Entrypoint = [ "${appRustBuild}/bin/${appName}" ];
+            Env = [ "SSL_CERT_FILE=${pkgs.cacert}/etc/ssl/certs/ca-bundle.crt" ];
+            Tag = "latest";
+          };
+          contents = [ appRustBuild pkgs.cacert ];
+        };
+      in {
+        packages = {
+          rustPackage = appRustBuild;
+          docker = dockerImage;
+        };
+        defaultPackage = dockerImage;
+        devShell = with pkgs; mkShell {
+          buildInputs = [
+            bacon
+            cargo
+            cargo-audit
+            cargo-auditable
+            cargo-tarpaulin
+            cargo-msrv
+            just
+            rust-analyzer
+            (rustVersion.override { extensions = [ "rust-src" ]; })
+            sqls
+            sqlx-cli
+          ];
+        };
+      });
+}