phundrak/dotfiles

Fork 0

Lucien Cartier-Tilet a800a292e2

[Fish] Automatically launch the Gnome Keyring when logging in

2021-11-18 20:13:24 +01:00

25 KiB

Raw Blame History

Fish config

Presentation
Fish from within Emacs
Tramp remote access
Regular fish shell appearance
Global variables
- Development
- $PATH
Abbreviations
- System monitoring
- System management (packages and services)
  - Package management
  - Service management
- Development
  - CMake
  - Docker
  - Text editors
  - Compilation
  - Git
- LaTeX
- Some security measures
- Typos
- Misc
  - Media
  - Sudo
  - History
  - Compression
  - exa
  - Network Management
  - NordVPN
  - Wget
Last thing before we’re done

Presentation

The file present in ~/.config/fish/config.fish is the configuration file for the fish shell. It contains custom functions, environment variables and abbreviations.

Just in case, we might need sometimes to declare the fish function fish_title as true, so let’s do so.

function fish_title
    true
end

Fish from within Emacs

I sometimes call fish from within emacs, with M-x ansi-term. In this case, the variable TERM needs to have the value eterm-color.

if test -n "$EMACS"
    set -x TERM eterm-color
end

Tramp remote access

When accessing from a remote machine our computer from Emacs, tramp needs a precise shell appearance: a simple $ followed by a space after which to put the commands it needs to execute, and nothing else. Due to this, let’s deactivate and redefine some of the functions defining the appearance of fish.

if test "$TERM" = "dumb"
    function fish_prompt
        echo "\$ "
    end
    function fish_right_prompt; end
    function fish_greeting; end
    function fish_title; end
end

Regular fish shell appearance

Now, there is only one function I modify when it comes to the appearance of fish when I’m the one using it: the fish_greeting function. I use it to give me an overview of my computer’s status, including its hostname, uptime, disks usage, ram usage, swap usage, and networking.

set RED '\033[0;31m'
set GREEN '\033[0;32m'
set NC '\033[0m'

function display_slider # used total
    set -l slider_length 38
    set -l used $argv[1]
    set -l total $argv[2]
    set -l used_slider (math -s0 "($used * $slider_length) / $total")
    set -l unused_slider (math -s0 "$slider_length - $used_slider")
    echo -en "["
    echo -en $RED
    echo -en (string repeat -n $used_slider '=')
    echo -en $GREEN
    echo -en (string repeat -n $unused_slider '=')
    echo -en $NC
    echo -en "]"
end

function fish_greeting
    set -l ruler_length 79
    set -l ruler (string repeat -n $ruler_length "=")

    set -l osname (cat /etc/os-release | grep -i pretty_name | sed 's/.*"\(.*\)".*/\1/')
    set -l uptime (uptime -p | sed 's/up //')

    set -l root (df -Ph | grep -E "/\$")
    set -l root_p (echo $root | awk '{print $5}' | tr -d '%')
    set -l root_used (echo $root | awk '{print $3}')
    set -l root_total (echo $root | awk '{print $2}')

    set -l ram (free -tm | grep Mem)
    set -l ram_total (echo $ram | awk '{print $2}')
    set -l ram_used (echo $ram | awk '{print $3}')
    set -l ram_p (math -s0 "$ram_used / $ram_total * 100")

    set -l swap (free -tm | grep Swap)
    set -l swap_total (echo $swap | awk '{print $2}')
    set -l swap_used (echo $swap | awk '{print $3}')
    set -l swap_p (math -s0 "$swap_used / $swap_total * 100")

    set -l connections (nmcli c s | grep -E "wifi|ethernet" | grep -v '\-\-')
    set -l wifi (echo $connections | grep "wifi" | awk '{print $1}')
    set -l ethernet (test "$connections" = "*ethernet*" && echo -e $GREEN"UP"$NC || echo -e $RED"DOWN"$NC)
    set -l wifi (test -n wifi && echo -e $GREEN$wifi$NC || echo - $RED"DOWN"$NC)

    echo $ruler
    printf "OS......: %-30sKernel: %s %s\n" $osname (uname -s) (uname -r)
    printf "Hostname: %-30sUptime: %s\n" (hostname) $uptime
    printf "Ethernet: %-41sWifi..: %s\n" $ethernet $wifi
    printf "Disks...: %-6s %s %6s / %6s (%2d%%)\n" "/" (display_slider $root_p 100) $root_used $root_total $root_p

    # loop other mountpoints
    for mp in (df -Ph 2> /dev/null | egrep "sd|tank|nvme" | egrep -v "boot|/\$")
        set -l mp_p (echo $mp | awk '{print $5}' | tr -d '%')
        set -l mp_used (echo $mp | awk '{print $3}')
        set -l mp_total (echo $mp | awk '{print $2}')
        set -l mp_name (echo $mp | awk '{print $6}')
        printf "          %-6s %s %6s / %6s (%2d%%)\n" $mp_name (display_slider $mp_p 100) $mp_used $mp_total $mp_p
    end

    printf "Ram.....:        %s %5dM / %5dM (%2d%%)\n" (display_slider $ram_used $ram_total) $ram_used $ram_total $ram_p
    printf "Swap....:        %s %5dM / %5dM (%2d%%)\n" (display_slider $swap_used $swap_total) $swap_used $swap_total $swap_p
    echo $ruler
end

The theme I use for fish is bobthefish, which by default puts a really long timestamp to the right of the prompt. I want something shorter, so here is the variable to set, using the format specified in date(1).

set -g theme_date_format "+%g-%m-%d %H:%M:%S"

I also wish to have a kinda different newline prompt, so let’s set it:

set -g theme_newline_prompt 'λ '

Finally, let’s set our prompt’s theme to the Nord theme.

set -g theme_color_scheme nord

Global variables

In order to keep some other code clean, I set the $BROWSER variable so I don’t have to call my web browser directly but rather with this variable.

set -gx BROWSER firefox

Sometimes, software will rely on SUDO_ASKPASS to get a GUI from which it can get the sudo password. So, let’s declare it.

set -gx SUDO_ASKPASS ~/.local/bin/askpass

In general, I prefer using bat to less, although the former relies on the latter, but bat provides nice wrapping around less, including syntax highlighting. Let’s set the manpager to bat then:

set -x MANPAGER "sh -c 'col -bx | bat -l man -p'"

set -x XMODIFIERS

if test -n "$DESKTOP_SESSION"
    set -x (gnome-keyring-daemon --start | string split "=")
end

Development

Now, let’s declare our editor of choice, EmacsClient; not Emacs itself since it will most often be just quick edits, nothing too heavy, if it is called from the EDITOR variable (from Git, for example), or from the VISUAL variable.

set -gx EDITOR emacsclient -c
set -gx VISUAL emacsclient -c

We also need to set the path to the Dart SDK.

set -gx DART_SDK /opt/dart-sdk/bin

And we also need to specify where the Android SDK it located.

set -gx ANDROID_HOME $HOME/Android/Sdk

Still related to Dart and Flutter development,

set -gx CHROME_EXECUTABLE /usr/bin/chromium

Next, we have two variables from Deno, the Node.js destroyer. Its base directory will be set in my XDG config directory, and its binaries will be located in my local binaries directory (see below).

set -gx DENO_DIR $HOME/.config/deno
set -gx DENO_INSTALL_ROOT $HOME/.local/bin/deno

Finally, some development packages require the PKG_CONFIG_PATH to be set, so let’s do so.

set -gx PKG_CONFIG_PATH /usr/local/lib/pkgconfig/ $PKG_CONFIG_PATH

`$PATH`

A variable available with the fish shell is fish_user_paths which lists custom paths to binaries specified by the user. Using this variable ensures they are included in the $PATH variable only once without the need to set it directly. For instance, my PATH variable needs Rust’s Cargo’s binaries, Go’s binaries, my own executables, and some more.

additional path	what it leads to
$HOME/.pub-cache/bin	Dart binaries and executables
$HOME/.local/bin	Custom executables, see /phundrak/dotfiles/src/commit/df161b7fde93d6cbf177cba837ea3d4fbebef0da/org/config/bin.org
$HOME/go/bin	Go binaries and executables
$HOME/.cargo/bin	Rust binaries and executables
$HOME/.gem/ruby/2.6.0/bin	Ruby binaries and executables
$HOME/.cabal/bin	Haskel binaries

$HOME/.pub-cache/bin \
$HOME/.local/bin \
$HOME/go/bin \
$HOME/.cargo/bin \
$HOME/.gem/ruby/2.6.0/bin \
$HOME/.cabal/bin

So, let’s set our user paths:

set -g fish_user_paths \
<<generate-extra-paths()>>

Abbreviations

Abbreviations are a great way to keep correctly track of which commands are run in the shell without polluting the history of the shell with obscure commands. When typing an abbreviation, fish will replace it with replace it with its expanded equivalent. Below are some of the abbreviations I use. Be aware some of them that invoke GUI programs can be invoked through devour which will make the terminal disappear while the program runs, and once the GUI program exists the terminal window will come back.

System monitoring

Here I have some abbreviations which are quite useful when performing some system monitoring. With df, we can get an overview of our filesystem usage, while with diskspace we get some more precise information. meminfo is a call to free with sane defaults, and similar to meminfo, we also have gpumeminfo so we can get a quick look at the memory-related logs of our X session. I also declared cpuinfo an alias of lscpu in order to keep consistent with meminfo. pscpu gives us information on what the CPU is running right now, and pscpu10 limits that to the top 10 threads. Similarly, psmem gives us information on the memory usage of the current threads, and psmem10 only the ten most important threads in terms of memory usage.

abbreviation	command
df	df -H
diskspace	sudo df -h \| grep -E "sd\|lv\|Size"
du	du -ch
meminfo	free -m -l -t
gpumeminfo	grep -i –color memory /var/log/Xorg.0.log
cpuinfo	lscpu
pscpu	ps auxf \| sort -nr -k 3
pscpu10	ps auxf \| sort -nr -k 3 \| head -10
psmem	ps auxf \| sort -nr -k 4
psmem10	ps auxf \| sort -nr -k 4 \| head -10

<<generate-abbr(table=mgmt-abbr)>>

System management (packages and services)

I added some of these abbreviations due to how often I have to write the whole thing.

Package management

The first command is remove which removes a package from my system, as well as its dependencies no longer needed. p. pacman's or paru's. This is why I simply type purge. And if I want to simply seach among the pacman repos, I can type search. Otherwise, if I want to include AUR results, I’ll use paru.

abbreviation	command
remove	sudo pacman -Rsc
purge	paru -Sc

<<generate-abbr(table=pm-abbr)>>

Service management

I don’t have the muscle memory of systemctl. So instead, I simply type c when I want to do something user service related. And if I want to manipulate system services, I can instead type a simple capital S.

abbreviation	command
s	systemctl
suser	systemctl –user

<<generate-abbr(table=service-abbr)>>

Development

A good amount of these commands are development related, especially when it comes to compilation or Docker.

CMake

I have the following abbreviations so I can quickly run CMake and create a configuration for debug or release profiles.

abbreviation	command
cdebug	cmake -DCMAKE_BUILD_TYPE=Debug
crelease	cmake -DCMAKE_BUILD_TYPE=Release