{
  description = "ROR development environment";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay.url = "github:oxalica/rust-overlay";
  };

  outputs = { self, nixpkgs, flake-utils, rust-overlay, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs { inherit system overlays; };
        rustVersion = (pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml);
        rustPlatform = pkgs.makeRustPlatform {
          cargo = rustVersion;
          rustc = rustVersion;
        };

        appName = "roll-one-ring";
        cargoToml = builtins.fromTOML (builtins.readFile ./Cargo.toml);
        version = cargoToml.package.version;
        appRustBuild = rustPlatform.buildRustPackage {
          pname = appName;
          version = version;
          src = ./.;
          cargoLock.lockFile = ./Cargo.lock;
        };

        makeDockerImage = tag: pkgs.dockerTools.buildLayeredImage {
          name = "phundrak/${appName}";
          inherit tag;
          config = {
            Entrypoint = ["${appRustBuild}/bin/${appName}"];
            Env = [ "SSL_CERT_FILE=${pkgs.cacert}/etc/ssl/certs/ca-bundle.crt" ];
          };
          contents = [appRustBuild pkgs.cacert];
        };

        dockerImageLatest = makeDockerImage "latest";
        dockerImageVersioned = makeDockerImage version;

      in {
        packages = {
          rustPackage = appRustBuild;
          docker = dockerImageLatest;
          docker-versioned = dockerImageVersioned;
        };
        defaultPackage = dockerImageLatest;
        apps = {
          version = {
            type = "app";
            program = "${pkgs.writeShellScript "version" ''
              echo "${version}"
            ''}";
          };
        };
        devShell = with pkgs; mkShell {
          buildInputs = [
            bacon
            cargo-deny
            cargo-msrv
            cargo-tarpaulin
            just
            rustVersion
            sqls
          ];
        };
      }
    );
}