refactor!: switch to dendritic pattern

BREAKING CHANGE: complete reorganization of the repository
2026-09-30 18:36:06 +02:00
parent 12684b4e9c
commit 5f4a7a4a42
323 changed files with 7117 additions and 7380 deletions
@@ -0,0 +1,108 @@
+{
+  flake.modules.homeManager.zsh = {
+    config,
+    lib,
+    pkgs,
+    ...
+  }:
+    with lib; let
+      cfg = config.home.shell.zsh;
+    in {
+      options.home.shell.zsh = {
+        enable = lib.mkEnableOption "Enables zsh";
+        abbrs = lib.mkOption {
+          type = types.attrsOf types.str;
+          default = {};
+          example = {
+            cp = "cp -i";
+            lns = "ln -si";
+          };
+        };
+        autocompletion = mkOption {
+          type = types.bool;
+          default = config.home.shell.autocompletion;
+          example = true;
+        };
+        eatIntegration = mkEnableOption "Enable Emacs Eat integration";
+        zshrcExtra = lib.mkOption {
+          type = types.lines;
+          default = "";
+        };
+      };
+
+      config = lib.mkIf cfg.enable {
+        programs.zsh = {
+          enable = true;
+          autocd = true;
+          autosuggestion = {
+            enable = true;
+            strategy = ["match_prev_cmd" "completion"];
+          };
+          enableCompletion = cfg.autocompletion;
+          enableVteIntegration = true;
+          history = {
+            findNoDups = true;
+            ignoreAllDups = true;
+            ignoreDups = true;
+            ignoreSpace = true;
+            path = "${config.xdg.dataHome}/zsh/zsh_history";
+            saveNoDups = true;
+          };
+          historySubstringSearch.enable = true;
+          initContent = with lib;
+            concatLines [
+              ''
+                bindkey -e
+                bindkey '^p' history-search-backward
+                bindkey '^n' history-search-forward
+
+                # Completion styling
+                zstyle ':completion:*' matcher-list 'm:{a-z}={A-Za-z}'
+                zstyle ':completion:*' list-colors "''${(s.:.)LS_COLORS}"
+                zstyle ':completion:*' menu no
+                zstyle ':fzf-tab:complete:cd:*' fzf-preview '${pkgs.eza}/bin/eza $realpath'
+              ''
+              (strings.optionalString cfg.eatIntegration ''[ -n "$EAT_SHELL_INTEGRATION_DIR" ] && source "$EAT_SHELL_INTEGRATION_DIR/zsh"'')
+              (strings.optionalString config.home.dev.vcs.jj.shellCompletion ''
+                autoload -U compinit
+                compinit
+                source <(jj util completion zsh)
+              '')
+              cfg.zshrcExtra
+            ];
+          oh-my-zsh = {
+            enable = true;
+            plugins = [
+              "dirhistory"
+              "sudo"
+            ];
+          };
+          plugins = [
+            {
+              name = "fzf-tab";
+              src = pkgs.fetchFromGitHub {
+                owner = "Aloxaf";
+                repo = "fzf-tab";
+                rev = "v1.2.0";
+                sha256 = "sha256-q26XVS/LcyZPRqDNwKKA9exgBByE0muyuNb0Bbar2lY=";
+              };
+            }
+            {
+              name = "zsh-autopair";
+              src = pkgs.fetchFromGitHub {
+                owner = "hlissner";
+                repo = "zsh-autopair";
+                rev = "449a7c3d095bc8f3d78cf37b9549f8bb4c383f3d";
+                sha256 = "sha256-3zvOgIi+q7+sTXrT+r/4v98qjeiEL4Wh64rxBYnwJvQ=";
+              };
+            }
+          ];
+          syntaxHighlighting.enable = true;
+          zsh-abbr = {
+            enable = true;
+            abbreviations = cfg.abbrs;
+          };
+        };
+      };
+    };
+}