Add new variables to the README

Check for compatibility with all version of Emacs since Emacs 25.1

Add Cask file for managing dependencies in CI

Add badge in README for CI

.github/workflows/workflow.yml

@@ -0,0 +1,46 @@
+name: CI
+on:
+  push:
+  pull_request:
+  workflow_dispatch:
+
+jobs:
+  check-compatibility:
+    runs-on: ubuntu-latest
+    strategy:
+      fail-fast: false
+      matrix:
+        emacs_version:
+          - 25.1
+          - 25.2
+          - 25.3
+          - 26.1
+          - 26.2
+          - 26.3
+          - 27.1
+          - 27.2
+          - 28.1
+          - snapshot
+    steps:
+      - uses: actions/checkout@v3
+      - uses: purcell/setup-emacs@master
+        with:
+          version: ${{ matrix.emacs_version }}
+      - uses: actions/cache@v2
+        id: cache-cask-packages
+        with:
+          path: .cask
+          key: cache-cask-packages-000
+      - uses: actions/cache@v2
+        id: cache-cask-executable
+        with:
+          path: ~/.cask
+          key: cache-cask-executable-000
+      - name: "Cask setup"
+        uses: cask/setup-cask@master
+        if: steps.cask-cache-executable.outputs.cache-hit != 'true'
+      - name: "Install Cask dependencies"
+        run: cask install
+        if: steps.cask-cache-executable.outputs.cache-hit != 'true'
+      - name: "Check version compatibility"
+        run: make all

Cask

@@ -0,0 +1,7 @@
+(source melpa)
+(source gnu)
+
+(package-file "eshell-info-banner.el")
+
+(development
+ (depends-on "s"))

Makefile

@@ -0,0 +1,11 @@
+# -*- indent-tabs-mode: t -*-
+
+export EMACS ?= $(shell which emacs)
+CASK ?= $(shell which cask)
+
+all: compile
+
+compile:
+	${CASK} exec ${EMACS} -Q --script bin/compile-package.el 2>&1 | grep -A 2 -E "([Ee]rror|[Ww]arning):" && exit 1 || exit 0
+
+.PHONY: all compile

README.org

@@ -3,13 +3,14 @@
 #+email: lucien@phundrak.com
 [[https://melpa.org/#/eshell-info-banner][file:https://melpa.org/packages/eshell-info-banner-badge.svg]]
 [[https://stable.melpa.org/#/eshell-info-banner][file:https://stable.melpa.org/packages/eshell-info-banner-badge.svg]]
+[[https://github.com/Phundrak/eshell-info-banner.el/actions/workflows/workflow.yml][file:https://github.com/Phundrak/eshell-info-banner.el/actions/workflows/workflow.yml/badge.svg]]
 
 * Introduction
 ~eshell-info-banner.el~ is a utility for creating an informative banner,
 akin to ~fish_greeting~ but for Eshell. But an image is worth a thousand
 words, let’s see how it looks like:
 
-#+caption: Screenshot of the default Eshell information banner
+#+caption: Screenshot of the default Eshell information banner (using the nord theme from ~doom-themes~)
 [[file:img/screenshot.png]]
 
 This will be displayed every time you open a new Eshell instance, or
@@ -22,15 +23,23 @@ macOS. PR are welcome if you want to fix that!
 * Table of Contents                                                :TOC_2_gh:
 - [[#introduction][Introduction]]
 - [[#recent-breaking-changes][Recent Breaking Changes]]
+  - [[#081][~0.8.1~]]
   - [[#070][~0.7.0~]]
 - [[#installation][Installation]]
 - [[#customizing][Customizing]]
+  - [[#custom-variables][Custom Variables]]
+  - [[#faces][Faces]]
 - [[#my-computer-doesnt-have-a-battery-will-this-still-work][My computer doesn’t have a battery, will this still work?]]
 - [[#advice-for-windows-users][Advice for Windows users]]
 - [[#contributing][Contributing]]
 - [[#license][License]]
 
 * Recent Breaking Changes
+** ~0.8.1~
+Version ~0.8.1~ removes the optional argument ~REMOTE~ from
+~eshell-info-banner--executable-find~. It now only acts according to the
+user’s preference set with ~eshell-info-banner-tramp-aware~.
+
 ** ~0.7.0~
 Version ~0.7.0~ renames several functions to conform with the Elisp
 Coding Conventions.
@@ -89,6 +98,7 @@ There is probably a similar way to install it with pure ~straight.el~ or
 a PR to add some more installation instructions!
 
 * Customizing
+** Custom Variables
 A couple of variables can be edited by the user in order to configure
 ~eshell-info-banner.el~:
 - ~eshell-info-banner-partition-prefixes~ :: Filter for which
@@ -99,6 +109,15 @@ A couple of variables can be edited by the user in order to configure
   set its value to ~("/dev" "zroot")~.
 
   Default value: ~("/dev")~
+- ~eshell-info-banner-filter-duplicate-partitions~ :: Try to filter
+  out duplicate partitions. Two partitions are considered duplicate if
+  they have the same size and amount of space used.
+
+  Default value: ~nil~
+- ~eshell-info-banner-exclude-partitions~ :: List of pattens to exclude
+  from the partition list.
+
+  Default value: ~nil~
 - ~eshell-info-banner-shorten-path-from~ :: Maximum length of the mount
   path of a partition before it gets abbreviated. Set it to ridiculous
   numbers in order to disable it (something like ~1000~ should be more
@@ -143,7 +162,19 @@ A couple of variables can be edited by the user in order to configure
   this custom variable.
 
   Default value: ~duf~
+- ~eshell-info-banner-file-size-flavor~ :: This variable reflects the
+  possible values passed to the function ~file-size-human-readable~. It
+  can hold one of these three values:
+  - ~nil~
+  - ~si~
+  - ~iec~
+  Since the value ~iec~ generates longer file size prefixes, progress
+  bars become slightly shorter. For more details on this option, see
+  the documentation of ~file-size-human-readable~.
 
+  Default value: ~nil~
+
+** Faces
 Don’t like the colors used by the package? They should follow by
 default your theme, but you can customize the following faces:
 - ~eshell-info-banner-background-face~ :: Used for filling the empty
@@ -168,10 +199,9 @@ line if you have one. If you don’t have a battery, the only difference
 is you will have one less line than laptop users.
 
 * Advice for Windows users
-Currently, the partitions detection is done only with the ~duf~
-command-line utility. If you want a list of your partitions, I
-strongly encourage you to install it on your system. See
-[[https://github.com/muesli/duf#windows]].
+Currently, ~eshell-info-banner~ can only look for your partitions with
+~duf~. If you want a list of your partitions, I strongly encourage you
+to install it on your system. See [[https://github.com/muesli/duf#windows][muesli/duf]].
 
 * Contributing
 See [[file:CONTRIBUTING.org]].

bin/compile-package.el

@@ -0,0 +1 @@
+(byte-recompile-directory "." 0 'force)

eshell-info-banner.el

@@ -2,8 +2,8 @@
 
 ;; Author: Lucien Cartier-Tilet <lucien@phundrak.com>
 ;; Maintainer: Lucien Cartier-Tilet <lucien@phundrak.com>
-;; Version: 0.7.7
-;; Package-Requires: ((emacs "25.1") (f "0.20") (s "1"))
+;; Version: 0.8.8
+;; Package-Requires: ((emacs "25.1") (s "1"))
 ;; Homepage: https://github.com/Phundrak/eshell-info-banner.el
 
 ;; This file is not part of GNU Emacs
@@ -38,7 +38,7 @@
 ;;; Code:
 
 (require 'cl-lib)
-(require 'f)
+(require 's)
 (require 'em-banner)
 (require 'json)
 (require 'seq)
@@ -60,55 +60,38 @@
                                         ;              Constants              ;
 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
+(defconst eshell-info-banner-path-separator
+  (substring-no-properties (file-relative-name (expand-file-name "x" "y")) 1 2)
+  "File separator used by the current operating system.")
+
 (defconst eshell-info-banner--min-length-left 8
   "Minimum length of text on the left hand side of the banner.")
 
 (eval-when-compile
   (defconst eshell-info-banner--macos-versions
-    '(("10.4"  . "Mac OS X Tiger")
-      ("10.5"  . "Mac OS X Leopard")
-      ("10.6"  . "Mac OS X Snow Leopard")
-      ("10.7"  . "Mac OS X Lion")
-      ("10.8"  . "OS X Mountain Lion")
-      ("10.9"  . "OS X Mavericks")
-      ("10.10" . "OS X Yosemite")
-      ("10.11" . "OS X El Capitan")
-      ("10.12" . "macOS Sierra")
-      ("10.13" . "macOS High Sierra")
-      ("10.14" . "macOS Mojave")
-      ("10.15" . "macOS Catalina")
-      ("10.16" . "macOS Big Sur")
-      ("11.0"  . "macOS Big Sur")
-      ("11.1"  . "macOS Big Sur")
-      ("11.2"  . "macOS Big Sur")
-      ("11.3"  . "macOS Big Sur")
-      ("11.4"  . "macOS Big Sur")
-      ("11.5"  . "macOS Big Sur")
-      ("11.6"  . "macOS Big Sur"))
+    '(("^10\\.0\\."  . "Mac OS X Cheetah")
+      ("^10\\.1\\."  . "Mac OS X Puma")
+      ("^10\\.2\\."  . "Mac OS X Jaguar")
+      ("^10\\.3\\."  . "Mac OS X Panther")
+      ("^10\\.4\\."  . "Mac OS X Tiger")
+      ("^10\\.5\\."  . "Mac OS X Leopard")
+      ("^10\\.6\\."  . "Mac OS X Snow Leopard")
+      ("^10\\.7\\."  . "Mac OS X Lion")
+      ("^10\\.8\\."  . "OS X Mountain Lion")
+      ("^10\\.9\\."  . "OS X Mavericks")
+      ("^10\\.10\\." . "OS X Yosemite")
+      ("^10\\.11\\." . "OS X El Capitan")
+      ("^10\\.12\\." . "macOS Sierra")
+      ("^10\\.13\\." . "macOS High Sierra")
+      ("^10\\.14\\." . "macOS Mojave")
+      ("^10\\.15\\." . "macOS Catalina")
+      ("^10\\.16\\." . "macOS Big Sur")
+      ("^11\\."      . "macOS Big Sur")
+      ("^12\\."      . "macOS Monterey"))
     "Versions of OSX and macOS and their name."))
 
-
-;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
-                                        ;                Macros               ;
-;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
-
-(defmacro eshell-info-banner--with-face (str &rest properties)
-  "Helper macro for applying face `PROPERTIES' to `STR'."
-  `(propertize ,str 'face (list ,@properties)))
-
-(defun eshell-info-banner--executable-find (program &optional remote)
-  (if (version< emacs-version "27.1")
-      (let ((default-directory (if (and eshell-info-banner-tramp-aware
-                                        remote)
-                                   default-directory
-                                 "~")))
-        (executable-find program))
-    (executable-find program remote)))
-
-(defun eshell-info-banner--shell-command-to-string (command)
-  "Execute shell command COMMAND and return its output as a string.
-Ensures the command is ran with LANG=C."
-  (shell-command-to-string (format "LANG=C %s" command)))
+(defconst eshell-info-banner--posix-shells '("bash" "zsh" "sh")
+  "List of POSIX-compliant shells to run external commands through.")
 
 
 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
@@ -119,56 +102,77 @@ Ensures the command is ran with LANG=C."
   "Make `eshell-info-banner' TRAMP aware."
   :group 'eshell-info-banner
   :type 'boolean
-  :safe #'booleanp
-  :version "0.3.0")
+  :safe #'booleanp)
 
 (defcustom eshell-info-banner-shorten-path-from 7
   "From which length should a path be shortened?"
   :group 'eshell-info-banner
   :type 'integer
-  :safe #'integer-or-marker-p
-  :version "0.1.0")
+  :safe #'integer-or-marker-p)
 
 (defcustom eshell-info-banner-width 80
   "Width of the info banner to be shown in Eshell."
   :group 'eshell-info-banner
   :type 'integer
-  :safe #'integer-or-marker-p
-  :version "0.1.0")
+  :safe #'integer-or-marker-p)
 
 (defcustom eshell-info-banner-progress-bar-char "="
   "Character to fill the progress bars with."
   :group 'eshell-info-banner
   :type 'string
-  :safe #'stringp
-  :version "0.1.0")
+  :safe #'stringp)
 
 (defcustom eshell-info-banner-warning-percentage 75
   "When to warn about a percentage."
   :group 'eshell-info-banner
   :type 'float
-  :safe #'floatp
-  :version "0.1.0")
+  :safe #'floatp)
 
 (defcustom eshell-info-banner-critical-percentage 90
   "When a percentage becomes critical."
   :group 'eshell-info-banner
   :type 'float
-  :safe #'floatp
-  :version "0.1.0")
+  :safe #'floatp)
 
 (defcustom eshell-info-banner-partition-prefixes '("/dev")
   "List of prefixes for detecting which partitions to display."
   :group 'eshell-info-banner
-  :type 'list
-  :version "0.3.0")
+  :type 'list)
+
+(defcustom eshell-info-banner-filter-duplicate-partitions nil
+  "Whether to filter duplicate partitions.
+
+Two partitions are considered duplicate if they have the same
+size and amount of space used."
+  :group 'eshell-info-banner
+  :type 'boolean)
+
+(defcustom eshell-info-banner-exclude-partitions nil
+  "List of patterns to exclude from the partition list.
+
+Patterns are matched against the partition name with
+`string-match-p'."
+  :group 'eshell-info-banner
+  :type '(repeat string))
+
+(defmacro eshell-info-banner--executable-find (program)
+  "Find PROGRAM executable, possibly on a remote machine.
+This is a wrapper around `executable-find' in order to avoid
+issues with older versions of the functions only accepting one
+argument. `executable-find'’s remote argument has the value of
+`eshell-info-banner-tramp-aware'."
+  (if (version< emacs-version "27.1")
+      `(let ((default-directory (if eshell-info-banner-tramp-aware
+                                    default-directory
+                                  "~")))
+         (executable-find ,program))
+    `(executable-find ,program eshell-info-banner-tramp-aware)))
 
 (defcustom eshell-info-banner-duf-executable "duf"
   "Path to the `duf' executable."
   :group 'eshell-info-banner
   :type 'string
-  :safe #'stringp
-  :version "0.5.0")
+  :safe #'stringp)
 
 (defcustom eshell-info-banner-use-duf
   (if (eshell-info-banner--executable-find eshell-info-banner-duf-executable)
@@ -177,8 +181,14 @@ Ensures the command is ran with LANG=C."
   "If non-nil, use `duf' instead of `df'."
   :group 'eshell-info-banner
   :type 'boolean
-  :safe #'booleanp
-  :version "0.5.0")
+  :safe #'booleanp)
+
+(defcustom eshell-info-banner-file-size-flavor nil
+  "Display sizes with IEC prefixes."
+  :group 'eshell-info-banner
+  :type '(radio (const :tag "Default" nil)
+                (const :tag "SI" si)
+                (const :tag "IEC" iec)))
 
 
 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
@@ -205,6 +215,56 @@ Ensures the command is ran with LANG=C."
   "Face for `eshell-info-banner' progress bars displaying critical levels."
   :group 'eshell-info-banner)
 
+
+;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
+                                        ;         Macros and Utilities        ;
+;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
+
+(defmacro eshell-info-banner--with-face (str &rest properties)
+  "Helper macro for applying face PROPERTIES to STR."
+  `(propertize ,str 'face (list ,@properties)))
+
+(defun eshell-info-banner--shell-command-to-string (command)
+  "Execute shell command COMMAND and return its output as a string.
+Ensures the command is ran with LANG=C."
+  (let ((shell (or (seq-find (lambda (shell)
+                              (eshell-info-banner--executable-find shell))
+                            eshell-info-banner--posix-shells)
+                  "sh")))
+    (with-temp-buffer
+      (let ((default-directory (if eshell-info-banner-tramp-aware default-directory "~")))
+        (process-file shell nil t nil "-c" (concat "LANG=C " command))
+        (buffer-string)))))
+
+(defun eshell-info-banner--progress-bar-without-prefix (bar-length used total &optional newline)
+  "Display a progress bar without its prefix.
+Display a progress bar of BAR-LENGTH length, followed by an
+indication of how full the memory is with a human readable USED
+and TOTAL size.
+Optional argument NEWLINE: Whether to output a newline at the end
+of the progress bar."
+  (let ((percentage (if (= used 0)
+                        0
+                      (/ (* 100 used) total))))
+    (concat (eshell-info-banner--progress-bar bar-length percentage)
+            (format (if (equal eshell-info-banner-file-size-flavor 'iec)
+                        " %8s / %-8s (%3s%%)%s"
+                      " %6s / %-6s (%3s%%)%s")
+                    (file-size-human-readable used eshell-info-banner-file-size-flavor)
+                    (file-size-human-readable total eshell-info-banner-file-size-flavor)
+                    (eshell-info-banner--with-face
+                     (number-to-string percentage)
+                     :inherit (eshell-info-banner--get-color-percentage percentage))
+                    (if newline "\n" "")))))
+
+(defun eshell-info-banner--string-repeat (str times)
+  "Repeat STR for TIMES times."
+  (declare (pure t) (side-effect-free t))
+  (let (result)
+    (cl-dotimes (_ times)
+      (setq result (cons str result)))
+    (apply #'concat result)))
+
 
 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
                                         ;          Internal functions         ;
@@ -220,7 +280,7 @@ If the executable `uptime' is not found, return nil."
     (let ((uptime-str (eshell-info-banner--shell-command-to-string "uptime -p")))
       (if (not (seq-some (lambda (keyword)
                            (string-match-p keyword uptime-str))
-                         '("invalid" "illegal")))
+                         '("invalid" "illegal" "unknown")))
           (s-chop-prefix "up " (s-trim uptime-str))
         (let ((uptime-str (eshell-info-banner--shell-command-to-string "uptime")))
           (save-match-data
@@ -236,7 +296,7 @@ If the executable `uptime' is not found, return nil."
   path size used percent)
 
 (defun eshell-info-banner--get-longest-path (partitions)
-  "Return the length of the longest partition path in `PARTITIONS'.
+  "Return the length of the longest partition path in PARTITIONS.
 
 The returned value is in any case greater than
 `eshell-info-banner--min-length-left'."
@@ -246,34 +306,43 @@ The returned value is in any case greater than
                         (length (eshell-info-banner--mounted-partitions-path partition)))))))
 
 (defun eshell-info-banner--abbr-path (path &optional abbr)
-  "Remove `$HOME' from `PATH', abbreviate parent dirs if `ABBR' non nil.
+  "Remove `$HOME' from PATH, abbreviate parent dirs if ABBR non nil.
 
-Abbreviate `PATH' by removing the value of `HOME' if it is
-present in the former, and if `ABBR' is t then all parent
-directories of the current `PATH' are abbreviated to only one
-character.  If an abbreviated directory starts with a dot, then
-include it before the abbreviated name of the directory,
-e.g. \".config\" -> \".c\".
+Abbreviate PATH by removing the value of HOME if it is present in
+the former, and if ABBR is t then all parent directories of the
+current PATH are abbreviated to only one character. If an
+abbreviated directory starts with a dot, then include it before
+the abbreviated name of the directory, e.g. \".config\" ->
+\".c\".
 
-For public use, `PATH' should be a string representing a UNIX
-path.  For internal use, `PATH' can also be a list. If `PATH' is
-neither of these, an error will be thrown by the function."
+For public use, PATH should be a string representing a UNIX path.
+For internal use, PATH can also be a list. If PATH is neither of
+these, an error will be thrown by the function."
   (cond
-   ((stringp path) (abbreviate-file-name
-                    (if abbr
-                        (eshell-info-banner--abbr-path
-                         (f-split (eshell-info-banner--abbr-path path)))
-                      path)))
+   ((stringp path)
+    (let ((abbr-path (abbreviate-file-name path)))
+      (if abbr
+          (abbreviate-file-name
+           (eshell-info-banner--abbr-path
+            (split-string abbr-path eshell-info-banner-path-separator t)))
+        abbr-path)))
    ((null path) "")
    ((listp path)
-    (f-join (if (= (length path) 1)
-                (car path)
-              (let* ((dir        (car path))
-                     (first-char (substring dir 0 1)))
-                (if (string= "." first-char)
-                    (substring dir 0 2)
-                  first-char)))
-            (eshell-info-banner--abbr-path (cdr path))))
+    (let ((file (eshell-info-banner--abbr-path (cdr path)))
+          (directory (if (= (length path) 1)
+                         (car path)
+                       (let* ((dir        (car path))
+                              (first-char (substring dir 0 1)))
+                         (if (string= "." first-char)
+                             (substring dir 0 2)
+                           first-char)))))
+       (if (string= "" file)
+           directory
+         (let ((relative-p (not (file-name-absolute-p directory)))
+               (new-dir    (expand-file-name file directory)))
+           (if relative-p
+               (file-relative-name new-dir)
+             new-dir)))))
    (t (error "Invalid argument %s, neither stringp or listp" path))))
 
 (defun eshell-info-banner--get-mounted-partitions-duf ()
@@ -300,8 +369,8 @@ chosen. Relies on the `duf' command."
                    :path    (if (> (length mount-point) eshell-info-banner-shorten-path-from)
                                 (eshell-info-banner--abbr-path mount-point t)
                               mount-point)
-                   :size    (file-size-human-readable total)
-                   :used    (file-size-human-readable used)
+                   :size    total
+                   :used    used
                    :percent percent)))
               partitions)))
 
@@ -313,15 +382,15 @@ Common function between
 otherwise differ solely on the position of the mount point in the
 partition list. Its position is given by the argument
 MOUNT-POSITION."
-  (let ((partitions (cdr (split-string (eshell-info-banner--shell-command-to-string "df -lH")
+  (let ((partitions (cdr (split-string (eshell-info-banner--shell-command-to-string "df -l -k")
                                        (regexp-quote "\n")
                                        t))))
     (cl-remove-if #'null
                   (mapcar (lambda (partition)
                             (let* ((partition  (split-string partition " " t))
                                    (filesystem (nth 0 partition))
-                                   (size       (nth 1 partition))
-                                   (used       (nth 2 partition))
+                                   (size       (* (string-to-number (nth 1 partition)) 1024))
+                                   (used       (* (string-to-number (nth 2 partition)) 1024))
                                    (percent    (nth 4 partition))
                                    (mount      (nth mount-position partition)))
                               (when (seq-some (lambda (prefix)
@@ -334,7 +403,7 @@ MOUNT-POSITION."
                                  :size size
                                  :used used
                                  :percent (string-to-number
-                                           (string-trim-left percent (regexp-quote "%")))))))
+                                           (s-chop-suffix "%" percent))))))
                           partitions))))
 
 (defun eshell-info-banner--get-mounted-partitions-gnu ()
@@ -363,43 +432,67 @@ Return detected partitions as a list of structs.  See
 chosen.  Relies on the `df' command."
   (eshell-info-banner--get-mounted-partitions-df 8))
 
-(defun eshell-info-banner--get-mounted-partitions ()
+(defun eshell-info-banner--get-mounted-partitions-1 ()
   "Detect mounted partitions on the system.
 
 Return detected partitions as a list of structs."
   (if eshell-info-banner-use-duf
       (eshell-info-banner--get-mounted-partitions-duf)
     (pcase system-type
-       ((or 'gnu 'gnu/linux 'gnu/kfreebsd 'berkeley-unix)
-        (eshell-info-banner--get-mounted-partitions-gnu))
-       ((or 'ms-dos 'windows-nt 'cygwin)
-        (eshell-info-banner--get-mounted-partitions-windows))
-       ('darwin
-        (eshell-info-banner--get-mounted-partitions-darwin))
-       (other
-        (progn
+      ((or 'gnu 'gnu/linux 'gnu/kfreebsd 'berkeley-unix)
+       (eshell-info-banner--get-mounted-partitions-gnu))
+      ((or 'ms-dos 'windows-nt 'cygwin)
+       (eshell-info-banner--get-mounted-partitions-windows))
+      ('darwin
+       (eshell-info-banner--get-mounted-partitions-darwin))
+      (other
+       (progn
          (warn "Partition detection for %s not yet supported." other)
          nil)))))
 
+(defun eshell-info-banner--get-mounted-partitions ()
+  "Detect mounted partitions on the system.
+
+Take `eshell-info-banner-filter-duplicate-partitions' and
+`eshell-info-banner-exclude-partitions' into account."
+  (let ((partitions (eshell-info-banner--get-mounted-partitions-1)))
+    (when eshell-info-banner-filter-duplicate-partitions
+      (setq partitions
+            (cl-loop for partition in partitions
+                     with used = nil
+                     for signature =
+                     (format "%d-%d"
+                             (eshell-info-banner--mounted-partitions-size partition)
+                             (eshell-info-banner--mounted-partitions-used partition))
+                     unless (member signature used)
+                     collect partition and do (push signature used))))
+    (when eshell-info-banner-exclude-partitions
+      (setq partitions
+            (seq-filter (lambda (partition)
+                          (let ((path (eshell-info-banner--mounted-partitions-path
+                                       partition)))
+                            (not (seq-some
+                                  (lambda (pattern)
+                                    (string-match-p pattern path))
+                                  eshell-info-banner-exclude-partitions))))
+                        partitions)))
+    partitions))
+
 (defun eshell-info-banner--partition-to-string (partition text-padding bar-length)
-  "Display a progress bar showing how full a `PARTITION' is.
+  "Display a progress bar showing how full a PARTITION is.
 
 For TEXT-PADDING and BAR-LENGTH, see the documentation of
 `eshell-info-banner--display-memory'."
-  (let ((percentage (eshell-info-banner--mounted-partitions-percent partition)))
-    (concat (s-pad-right text-padding
-                         "."
-                         (eshell-info-banner--with-face
-                          (eshell-info-banner--mounted-partitions-path partition)
-                          :weight 'bold))
-            ": "
-            (eshell-info-banner--progress-bar bar-length percentage)
-            (format " %6s / %-6s (%3s%%)"
-                    (eshell-info-banner--mounted-partitions-used partition)
-                    (eshell-info-banner--mounted-partitions-size partition)
-                    (eshell-info-banner--with-face
-                     (number-to-string percentage)
-                     :inherit (eshell-info-banner--get-color-percentage percentage))))))
+  (concat (s-pad-right text-padding
+                       "."
+                       (eshell-info-banner--with-face
+                        (eshell-info-banner--mounted-partitions-path partition)
+                        :weight 'bold))
+          ": "
+          (eshell-info-banner--progress-bar-without-prefix
+           bar-length
+           (eshell-info-banner--mounted-partitions-used partition)
+           (eshell-info-banner--mounted-partitions-size partition))))
 
 (defun eshell-info-banner--display-partitions (text-padding bar-length)
   "Display the detected mounted partitions of the system.
@@ -424,19 +517,80 @@ For TEXT-PADDING and BAR-LENGTH, see the documentation of
                         "\n"
                         t)))
 
-(defun eshell-info-banner--get-memory-unix ()
-  "Get memory usage for UNIX systems.
-Compatible with Darwin and FreeBSD at least."
-  (let* ((command-to-mem (lambda (command)
-                           (string-to-number
+(defun eshell-info-banner--get-memory-unix-command-to-mem (command)
+  "Get the output of COMMAND corresponding to memory information.
+This function is to be only used on platforms which support sysctl."
+  (string-to-number
+   (s-trim
+    (car (last
+          (split-string (eshell-info-banner--shell-command-to-string command)
+                        " "
+                        t))))))
+
+(defun eshell-info-banner--get-memory-netbsd ()
+  "Get memory usage for NetBSD systems.
+See `eshell-info-banner--get-memory'."
+  (let* ((total (eshell-info-banner--get-memory-unix-command-to-mem "sysctl hw.physmem64"))
+         (used  (- total
+                   (* 1024 (string-to-number
                             (s-trim
-                             (cadr
-                              (split-string (eshell-info-banner--shell-command-to-string command)
-                                            " "
-                                            t)))))))
-    `(("RAM"
-       ,(apply command-to-mem '("sysctl hw.physmem"))
-       ,(apply command-to-mem '("sysctl hw.usermem"))))))
+                             (with-temp-buffer
+                               (insert-file-contents-literally "/proc/meminfo")
+                               (save-match-data
+                                 (string-match (rx bol
+                                                   "MemFree:"
+                                                   (* blank)
+                                                   (group (+ digit))
+                                                   (* blank)
+                                                   "kB")
+                                               (buffer-string))
+                                 (substring-no-properties (buffer-string)
+                                                          (match-beginning 1)
+                                                          (match-end 1))))))))))
+    `(("RAM" ,total ,used))))
+
+(defun eshell-info-banner--get-memory-darwin ()
+  "Get memory usage for Darwin systems.
+See `eshell-info-banner--get-memory'."
+  (let* ((total  (eshell-info-banner--get-memory-unix-command-to-mem "sysctl -n hw.memsize"))
+         (vmstat (with-temp-buffer
+                   (call-process "vm_stat" nil t nil)
+                   (buffer-string)))
+         (wired  (save-match-data
+                   (string-match (rx " wired" (* (not digit)) (+ blank) (group (+ digit)) ".")
+                                 vmstat)
+                   (* 1024 4
+                      (string-to-number (substring-no-properties vmstat
+                                                                 (match-beginning 1)
+                                                                 (match-end 1))))))
+         (active (save-match-data
+                   (string-match (rx " active" (* (not digit)) (+ blank) (group (+ digit)) ".")
+                                 vmstat)
+                   (* 1024 4
+                      (string-to-number (substring-no-properties vmstat
+                                                                 (match-beginning 1)
+                                                                 (match-end 1))))))
+         (compressed (save-match-data
+                       (if (string-match (rx " occupied" (* (not digit)) (+ blank) (group (+ digit)) ".")
+                                         vmstat)
+                           (* 1024 4
+                              (string-to-number (substring-no-properties vmstat
+                                                                         (match-beginning 1)
+                                                                         (match-end 1))))
+                         0))))
+    `(("RAM" ,total ,(+ wired active compressed)))))
+
+(defun eshell-info-banner--get-memory-unix ()
+  "Get memory usage for UNIX systems."
+  (cond ((and (equal system-type 'berkeley-unix)
+              (string-match-p "NetBSD" (eshell-info-banner--shell-command-to-string "uname")))
+         (eshell-info-banner--get-memory-netbsd))
+        ((equal system-type 'darwin)
+         (eshell-info-banner--get-memory-darwin))
+        (t
+         (let* ((total (eshell-info-banner--get-memory-unix-command-to-mem "sysctl hw.physmem"))
+                (used  (eshell-info-banner--get-memory-unix-command-to-mem "sysctl hw.usermem")))
+           `(("RAM" ,total ,used))))))
 
 (defun eshell-info-banner--get-memory-windows ()
   "Get memory usage for Window."
@@ -464,29 +618,20 @@ in bytes."
 (defun eshell-info-banner--memory-to-string (type total used text-padding bar-length)
   "Display a memory’s usage with a progress bar.
 
-The `TYPE' of memory will be the text on the far left, while
-`USED' and `TOTAL' will be displayed on the right of the progress
-bar.  From them, a percentage will be computed which will be used
-to display a colored percentage of the progress bar and it will
-be displayed on the far right.
+The TYPE of memory will be the text on the far left, while USED
+and TOTAL will be displayed on the right of the progress bar.
+From them, a percentage will be computed which will be used to
+display a colored percentage of the progress bar and it will be
+displayed on the far right.
 
-`TEXT-PADDING' will determine how many dots are necessary between
-`TYPE' and the colon.
+TEXT-PADDING will determine how many dots are necessary between
+TYPE and the colon.
 
-`BAR-LENGTH' determines the length of the progress bar to be
+BAR-LENGTH determines the length of the progress bar to be
 displayed."
-  (let ((percentage (if (= used 0)
-                        0
-                      (/ (* 100 used) total))))
-    (concat (s-pad-right text-padding "." type)
-            ": "
-            (eshell-info-banner--progress-bar bar-length percentage)
-            (format " %6s / %-6s (%3s%%)\n"
-                    (file-size-human-readable used)
-                    (file-size-human-readable total)
-                    (eshell-info-banner--with-face
-                     (number-to-string percentage)
-                     :inherit (eshell-info-banner--get-color-percentage percentage))))))
+  (concat (s-pad-right text-padding "." type)
+          ": "
+          (eshell-info-banner--progress-bar-without-prefix bar-length used total t)))
 
 (defun eshell-info-banner--display-memory (text-padding bar-length)
   "Display memories detected on your system.
@@ -498,10 +643,10 @@ bars will have this appearance:
 
 TYPE......: [=========] XXG / XXG  (XX%)
 
-`TEXT-PADDING': the space allocated to the text at the left of the
+TEXT-PADDING: the space allocated to the text at the left of the
 progress bar.
 
-`BAR-LENGTH': the length of the progress bar."
+BAR-LENGTH: the length of the progress bar."
   (mapconcat (lambda (mem)
                (eshell-info-banner--memory-to-string (nth 0 mem) (nth 1 mem)
                                                      (nth 2 mem) text-padding
@@ -513,7 +658,7 @@ progress bar.
                                         ; Display information ;;;;;;;;;;;;;;;;;
 
 (defun eshell-info-banner--get-color-percentage (percentage)
-  "Display a `PERCENTAGE' with its according face."
+  "Display a PERCENTAGE with its according face."
   (let ((percentage (if (stringp percentage)
                         (string-to-number percentage)
                       percentage)))
@@ -525,12 +670,12 @@ progress bar.
      (t 'eshell-info-banner-normal-face))))
 
 (defun eshell-info-banner--progress-bar (length percentage &optional invert)
-  "Display a progress bar `LENGTH' long and `PERCENTAGE' full.
+  "Display a progress bar LENGTH long and PERCENTAGE full.
 The full path will be displayed filled with the character
 specified by `eshell-info-banner-progress-bar-char' up to
-`PERCENTAGE' percents.  The rest will be empty.
+PERCENTAGE percents.  The rest will be empty.
 
-If `INVERT' is t, then consider the percentage to approach
+If INVERT is t, then consider the percentage to approach
 critical levels close to 0 rather than 100."
   (let* ((length-filled     (if (= 0 percentage)
                                 0
@@ -541,10 +686,12 @@ critical levels close to 0 rather than 100."
                              percentage)))
     (concat
      (eshell-info-banner--with-face "[" :weight 'bold)
-     (eshell-info-banner--with-face (s-repeat length-filled eshell-info-banner-progress-bar-char)
+     (eshell-info-banner--with-face (eshell-info-banner--string-repeat eshell-info-banner-progress-bar-char
+                                                                       length-filled)
                                     :weight 'bold
                                     :inherit (eshell-info-banner--get-color-percentage percentage-level))
-     (eshell-info-banner--with-face (s-repeat length-empty eshell-info-banner-progress-bar-char)
+     (eshell-info-banner--with-face (eshell-info-banner--string-repeat eshell-info-banner-progress-bar-char
+                                                                       length-empty)
                                     :weight 'bold
                                     :inherit 'eshell-info-banner-background-face)
      (eshell-info-banner--with-face "]" :weight 'bold))))
@@ -552,9 +699,9 @@ critical levels close to 0 rather than 100."
 (defun eshell-info-banner--display-battery (text-padding bar-length)
   "If the computer has a battery, display its level.
 
-Pad the left text with dots by `TEXT-PADDING' characters.
+Pad the left text with dots by TEXT-PADDING characters.
 
-`BAR-LENGTH' indicates the length in characters of the progress
+BAR-LENGTH indicates the length in characters of the progress
 bar.
 
 The usage of `eshell-info-banner-warning-percentage' and
@@ -562,7 +709,9 @@ The usage of `eshell-info-banner-warning-percentage' and
 thought of as the “percentage of discharge” of the computer.
 Thus, setting the warning at 75% will be translated as showing
 the warning face with a battery level of 25% or less."
-  (let ((battery-level (when (file-readable-p "/sys/") (battery))))
+  (let ((battery-level (unless (and (equal system-type 'gnu/linux)
+                                    (not (file-readable-p "/sys/")))
+                         (battery))))
     (if (or (null battery-level)
             (string= battery-level "Battery status not available")
             (string-match-p (regexp-quote "N/A") battery-level))
@@ -577,7 +726,9 @@ the warning face with a battery level of 25% or less."
                 (eshell-info-banner--progress-bar bar-length
                                                   percentage
                                                   t)
-                (s-repeat 17 " ")
+                (eshell-info-banner--string-repeat
+                 " "
+                 (if (equal eshell-info-banner-file-size-flavor 'iec) 21 17))
                 (format "(%3s%%)\n"
                         (eshell-info-banner--with-face
                          (number-to-string percentage)
@@ -644,7 +795,7 @@ If RELEASE-FILE is nil, use '/etc/os-release'."
                    (insert-file-contents (concat prefix "/bedrock/etc/bedrock-release"))
                    (buffer-string))))
         ;; Proxmox
-        ((eshell-info-banner--executable-find "pveversion" eshell-info-banner-tramp-aware)
+        ((eshell-info-banner--executable-find "pveversion")
          (let ((distro (eshell-info-banner--shell-command-to-string "pveversion")))
            (save-match-data
              (string-match "/\\([^/]+\\)/" distro)
@@ -652,9 +803,9 @@ If RELEASE-FILE is nil, use '/etc/os-release'."
                      (substring-no-properties distro
                                               (match-beginning 1)
                                               (match-end 1))))))
-        ((eshell-info-banner--executable-find "hostnamectl" eshell-info-banner-tramp-aware)
+        ((eshell-info-banner--executable-find "hostnamectl")
          (eshell-info-banner--get-os-information-from-hostnamectl))
-        ((eshell-info-banner--executable-find "lsb_release" eshell-info-banner-tramp-aware)
+        ((eshell-info-banner--executable-find "lsb_release")
          (eshell-info-banner--get-os-information-from-lsb-release))
         ((file-exists-p (concat prefix "/etc/os-release"))
          (eshell-info-banner--get-os-information-from-release-file))
@@ -683,15 +834,17 @@ If RELEASE-FILE is nil, use '/etc/os-release'."
   "Get the name of the current macOS or OSX system based on its VERSION."
   `(cond
     ,@(mapcar (lambda (major)
-               `((string-match-p (regexp-quote ,(car major))
-                                 ,version)
-                 ,(cdr major)))
+                `((string-match-p ,(car major)
+                                  ,version)
+                  ,(cdr major)))
               eshell-info-banner--macos-versions)
     (t "unknown version")))
 
 (defun eshell-info-banner--get-os-information-darwin ()
   "See `eshell-info-banner--get-os-information'."
-  `(,(eshell-info-banner--get-macos-name (s-trim (eshell-info-banner--shell-command-to-string "sw_vers -productVersion")))
+  `(,(eshell-info-banner--get-macos-name
+      (s-trim
+       (eshell-info-banner--shell-command-to-string "sw_vers -productVersion")))
     .
     ,(s-trim (eshell-info-banner--shell-command-to-string "uname -rs"))))
 
@@ -719,27 +872,31 @@ build number)."
 (defun eshell-info-banner ()
   "Banner for Eshell displaying system information."
   (let* ((default-directory (if eshell-info-banner-tramp-aware default-directory "~"))
-         (system-info   (eshell-info-banner--get-os-information))
-         (os            (car system-info))
-         (kernel        (cdr system-info))
-         (hostname      (if  eshell-info-banner-tramp-aware
-                            (or (file-remote-p default-directory 'host) (system-name))
-                          (system-name)))
-         (uptime        (eshell-info-banner--get-uptime))
-         (partitions    (eshell-info-banner--get-mounted-partitions))
-         (left-padding  (eshell-info-banner--get-longest-path partitions))
-         (left-text     (max (length os)
-                             (length hostname)))
-         (left-length   (+ left-padding 2 left-text)) ; + ": "
-         (right-text    (+ (length "Kernel: ")
-                           (max (length uptime)
-                                (length kernel))))
-         (tot-width     (max (+ left-length right-text 3)
-                             eshell-info-banner-width))
-         (middle-padding (- tot-width right-text left-padding 4))
+         (system-info       (eshell-info-banner--get-os-information))
+         (os                (car system-info))
+         (kernel            (cdr system-info))
+         (hostname          (if  eshell-info-banner-tramp-aware
+                                (or (file-remote-p default-directory 'host) (system-name))
+                              (system-name)))
+         (uptime             (eshell-info-banner--get-uptime))
+         (partitions         (eshell-info-banner--get-mounted-partitions))
+         (left-padding       (eshell-info-banner--get-longest-path partitions))
+         (left-text          (max (length os)
+                                  (length hostname)))
+         (left-length        (+ left-padding 2 left-text)) ; + ": "
+         (right-text         (+ (length "Kernel: ")
+                                (max (length uptime)
+                                     (length kernel))))
+         (tot-width          (max (+ left-length right-text 3)
+                                  eshell-info-banner-width))
+         (middle-padding     (- tot-width right-text left-padding 4))
 
-         (bar-length    (- tot-width left-padding 4 23)))
-    (concat (format "%s\n" (s-repeat tot-width eshell-info-banner-progress-bar-char))
+         (bar-length         (- tot-width left-padding 4 23))
+         (bar-length         (if (equal eshell-info-banner-file-size-flavor 'iec)
+                                 (- bar-length 4)
+                               bar-length)))
+    (concat (format "%s\n" (eshell-info-banner--string-repeat eshell-info-banner-progress-bar-char
+                                                              tot-width))
             (format "%s: %s Kernel.: %s\n"
                     (s-pad-right left-padding
                                  "."
@@ -753,7 +910,8 @@ build number)."
             (eshell-info-banner--display-battery left-padding bar-length)
             (eshell-info-banner--display-memory left-padding bar-length)
             (eshell-info-banner--display-partitions left-padding bar-length)
-            (format "\n%s\n" (s-repeat tot-width eshell-info-banner-progress-bar-char)))))
+            (format "\n%s\n" (eshell-info-banner--string-repeat eshell-info-banner-progress-bar-char
+                                                                tot-width)))))
 
 ;;;###autoload
 (defun eshell-info-banner-update-banner ()